dnl
dnl добавление поля Message-Id
dnl по умолчанию начиная с версии 4.30 поле Message-Id добавляется только в локально
dnl полученные сообщения (не по SMTP)
dnl NO			- ну добавлять поле MEssage-Id
dnl YES			- добавлять поле Message-Id во все сообщения
dnl ALL			- добавлять поле Message-Id во все сообщения
dnl RELAY		- добавлять поле Message-Id во все сообщения из рилеемых сетей
dnl AUTH		- добавлять поле Message-Id во все сообщения от аутентифицированных отправителей
dnl define(`confMESSAGE_ID_HEADER_ADD', `RELAY AUTH')dnl
dnl доменная часть поля Message-Id
dnl по умолчанию используется $primary_hostname
dnl define(`confMESSAGE_ID_HEADER_DOMAIN', `')dnl
dnl

ifelse(confMESSAGE_ID_HEADER_ADD, `YES', `define(`confMESSAGE_ID_HEADER_ADD',`ALL')')dnl

ifelse(SECTION, `MAIN', `dnl
ifdef(`confMESSAGE_ID_HEADER_DOMAIN', `ifelse(len(X`'confMESSAGE_ID_HEADER_DOMAIN), `1', `dnl
define(`confMESSAGE_ID_HEADER_DOMAIN', `$primary_hostname')
', `dnl
message_id_header_domain = confMESSAGE_ID_HEADER_DOMAIN
')', `dnl
define(`confMESSAGE_ID_HEADER_DOMAIN', `$primary_hostname')
')
')dnl
dnl
ifelse(SECTION, `ACL_CHECK_DATA', `dnl
dnl
ifdef(`confMESSAGE_ID_HEADER_ADD', `ifelse(confMESSAGE_ID_HEADER_ADD, `NO', `dnl', `dnl

ifelse(confMESSAGE_ID_HEADER_ADD, `ALL', `
	warn	condition	= ${if def:h_Message-ID:{no}{yes}}
		add_header	= Message-ID: <E${message_id}@confMESSAGE_ID_HEADER_DOMAIN>
',`
ifelse_strstr(confMESSAGE_ID_HEADER_ADD, `AUTH', `
	warn	condition	= ${if def:h_Message-ID:{no}{yes}}
		authenticated	= *
		add_header	= Message-ID: <E${message_id}@confMESSAGE_ID_HEADER_DOMAIN>
') dnl ifelse_strstr(confMESSAGE_ID_HEADER_ADD, `AUTH', `')
ifelse_strstr(confMESSAGE_ID_HEADER_ADD, `RELAY', `
	warn	condition	= ${if def:h_Message-ID:{no}{yes}}
		hosts		= +relay_from_hosts
		add_header	= Message-ID: <E${message_id}@confMESSAGE_ID_HEADER_DOMAIN>
') dnl ifelse_strstr(confMESSAGE_ID_HEADER_ADD, `RELAY', `')
') dnl ifelse(confMESSAGE_ID_HEADER_ADD, `ALL', `')

')') dnl ifdef(`confMESSAGE_ID_HEADER_ADD', `ifelse(confMESSAGE_ID_HEADER_ADD, `NO', `', `')')

') dnl ifelse(SECTION, `ACL_CHECK_DATA', `')