dnl
dnl Доставка в users maildirs
dnl
dnl локальная доставка (список)
dnl MBOX		- доставка в mailbox'ы в /var/mail
dnl 			с MBOX можно указывать через пробел:
dnl 			FILTERS	 - использование .forward в качестве фильтров
dnl 			PROCMAIL - использование .procmailrc в качестве фильтров
dnl MDIR_USER		- доставка в maildir'ы в $home/Maildir (еще не работает)
dnl 			с MDIR_USER можно указывать через пробел:
dnl 			FILTERS	 - использование .forward в качестве фильтров
dnl 			PROCMAIL - использование .procmailrc в качестве фильтров
dnl define(`confDELIVERY_TO', `MDIR_USERS FILTERS PROCMAIL')dnl
dnl
dnl при наличии MBOX или MDIR_USER в confDELIVERY_TO:
dnl
dnl 	место хранения алиасов:
dnl 	TEXT		- хранение алиасов в текстовом файле
dnl 	DBM		- хранение алиасов в DBM файле
dnl define(`confSYSTEM_ALIASES', `DBM')dnl
dnl
ifelse(SECTION, `ROUTERS', `dnl
##### delivery to users maildirs
system_aliases:
	driver			= redirect
ifdef(`confLOCAL_PART_SUFFIX', `ifelse(confLOCAL_PART_SUFFIX, `NO', `dnl', `dnl
	local_part_suffix       = confLOCAL_PART_SUFFIX
	local_part_suffix_optional
')') dnl ifdef(`confLOCAL_PART_SUFFIX', `ifelse(confLOCAL_PART_SUFFIX, `NO', `', `')')
	allow_fail
	allow_defer
ifdef(`confSYSTEM_ALIASES', `ifelse(confSYSTEM_ALIASES, `TEXT', `dnl
	require_files		= CONFDIR/aliases
	data			= ${lookup{$local_part}lsearch{CONFDIR/aliases}}
')') dnl ifdef(`confSYSTEM_ALIASES', `ifelse(confSYSTEM_ALIASES, `TEXT', `')')
ifdef(`confSYSTEM_ALIASES', `ifelse(confSYSTEM_ALIASES, `DBM', `dnl
	require_files		= CONFDIR/aliases.db
	data			= ${lookup{$local_part}dbm{CONFDIR/aliases.db}}
')') dnl ifdef(`confSYSTEM_ALIASES', `ifelse(confSYSTEM_ALIASES, `DBM', `')')
	user			= mailnull
	group			= mail
	file_transport		= address_file
	pipe_transport		= address_pipe

ifelse_strstr(confDELIVERY_TO, `PROCMAIL', `dnl
DELIVERY(`procmail')dnl
') dnl ifelse_strstr(confDELIVERY_TO, `PROCMAIL', `')

userforward:
	driver			= redirect
ifdef(`confLOCAL_PART_SUFFIX', `ifelse(confLOCAL_PART_SUFFIX, `NO', `dnl', `dnl
	local_part_suffix       = confLOCAL_PART_SUFFIX
	local_part_suffix_optional
')') dnl ifdef(`confLOCAL_PART_SUFFIX', `ifelse(confLOCAL_PART_SUFFIX, `NO', `', `')')
	check_local_user
	file			= $home/.forward
	no_verify
	no_expn
	check_ancestor
	file_transport		= address_file
	pipe_transport		= address_pipe
	reply_transport		= address_reply
	require_files		= $home/.forward
ifelse_strstr(confDELIVERY_TO, `FILTERS', `dnl
	allow_filter
') dnl ifelse_strstr(confDELIVERY_TO, `FILTERS', `')

DELIVERY(`backup_incoming')dnl

localuser:
	driver			= accept
ifdef(`confLOCAL_PART_SUFFIX', `ifelse(confLOCAL_PART_SUFFIX, `NO', `dnl', `dnl
	local_part_suffix       = confLOCAL_PART_SUFFIX
	local_part_suffix_optional
')') dnl ifdef(`confLOCAL_PART_SUFFIX', `ifelse(confLOCAL_PART_SUFFIX, `NO', `', `')')
	check_local_user
	transport		= local_delivery
ifelse_strstr(confDELIVERY_TO, `MDIR_VIRTUAL', `ifelse_strstr(confVIRT_MDIR_USERLIST, `DOMAINS_FILES', `
	condition		= ${if exists{confVIRT_MDIR_DOMAIN_SETTINGS/${domain}}{no}{yes}}
')') dnl ifelse_strstr(confDELIVERY_TO, `MDIR_VIRTUAL', `ifelse_strstr(confVIRT_MDIR_USERLIST, `DOMAINS_FILES', `')')
	ifdef(`confHEADERS_REMOVE_LOCALUSER', `headers_remove		= confHEADERS_REMOVE_LOCALUSER
')dnl
') dnl ifelse(SECTION, `ROUTERS', `')

ifelse(SECTION, `TRANSPORTS', `dnl
local_delivery:
	driver			= appendfile
	directory		= confMDIR_USER_MAILDIR
	delivery_date_add
	envelope_to_add
	return_path_add
	group			= mail
	mode			= 0640
	create_directory	= true
	directory_mode		= 750
	maildir_format		= true
	user			= $local_part
ifelse_strstr(confMAIL_BACKUP, `ROUTER_REDIRECT', `dnl
	headers_remove		= ${if eq{$local_part@$domain}{confMAIL_BACKUP_ADDR}{}{X-Recipients}}
') dnl ifelse_strstr(confMAIL_BACKUP, `ROUTER_REDIRECT', `')
') dnl ifelse(SECTION, `TRANSPORTS', `')