dnl
dnl поддержка клиентской SMTP Auth (список)
dnl
dnl NO          - не использовать SMTP Auth
dnl PLAIN       - использовать PLAIN SMTP Auth
dnl LOGIN       - использовать LOGIN SMTP Auth
dnl CRAM-MD5    - использовать CRAM-MD5 SMTP Auth
dnl define(`confSMTP_AUTH_CLIENT', `NO')dnl
dnl
dnl данные аутентификации указываются в файле CONFDIR/smtpauthdb в виде трех колонок,
dnl разделенных двоеточиями:
dnl host:login:password
dnl
dnl пример:
dnl mail.server:clientname:secret
dnl *:defaultclientname:defaultsecret
dnl

ifelse(SECTION, `MAIN', `dnl
hostlist hosts_try_auth		= lsearch;CONFDIR/smtpauthdb
')

ifelse(SECTION, `AUTHENTICATORS', `dnl

ifelse_strstr(confSMTP_AUTH_CLIENT, `PLAIN', `dnl
	client_auth_plain:
		driver			= plaintext
		public_name		= PLAIN
		client_send		= "^${extract{1}{::}{${lookup{$host}lsearch*{CONFDIR/smtpauthdb}{$value}fail}}}^${extract{2}{::}{${lookup{$host}lsearch*{CONFDIR/smtpauthdb}{$value}fail}}}"
')

ifelse_strstr(confSMTP_AUTH_CLIENT, `LOGIN', `dnl
	client_auth_login:
		driver			= plaintext
		public_name		= LOGIN
		client_send		= ": ${extract{1}{::}{${lookup{$host}lsearch*{CONFDIR/smtpauthdb}{$value}fail}}} : ${extract{2}{::}{${lookup{$host}lsearch*{CONFDIR/smtpauthdb}{$value}fail}}}"
')

ifelse_strstr(confSMTP_AUTH_CLIENT, `CRAM-MD5', `dnl
	client_cram_md5:
		driver			= cram_md5
		public_name		= CRAM-MD5
		client_name		= ${extract{1}{::}{${lookup{$host}lsearch*{CONFDIR/smtpauthdb}{$value}fail}}}
		client_secret		= ${extract{2}{::}{${lookup{$host}lsearch*{CONFDIR/smtpauthdb}{$value}fail}}}
')

')